ВЫБРАТЬ
	Склады.Ссылка КАК Склад,
	"Склад" КАК ТипОбъекта
ПОМЕСТИТЬ ВремСклады
ИЗ
	Справочник.Склады КАК Склады
ГДЕ
	НЕ Склады.ЭтоГруппа
{ГДЕ
	Склады.Ссылка.* КАК Склад}

ИНДЕКСИРОВАТЬ ПО
	Склад
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
	"ТоварДляГруппы" КАК ТипОбъекта,
	НоменклатураСХарактеристиками.Номенклатура КАК Номенклатура,
	НоменклатураСХарактеристиками.ЕдиницаИзмерения
ПОМЕСТИТЬ ВремНоменклатура
ИЗ
	(ВЫБРАТЬ РАЗЛИЧНЫЕ
		ТаблицаНоменклатуры.Номенклатура КАК Номенклатура,
		ТаблицаНоменклатуры.ЕдиницаИзмерения КАК ЕдиницаИзмерения
	ИЗ
		(ВЫБРАТЬ РАЗЛИЧНЫЕ
			Сегменты.Номенклатура КАК Номенклатура,
			Сегменты.Номенклатура.ЕдиницаИзмерения КАК ЕдиницаИзмерения
		ИЗ
			РегистрСведений.НоменклатураСегмента КАК Сегменты
		ГДЕ
			&ИспользуетсяОтборПоСегментуНоменклатуры
		{ГДЕ
			Сегменты.Сегмент.* КАК СегментНоменклатуры,
			Сегменты.Номенклатура.* КАК Номенклатура}
		
		ОБЪЕДИНИТЬ
		
		ВЫБРАТЬ
			Номенклатура.Ссылка,
			Номенклатура.ЕдиницаИзмерения
		ИЗ
			Справочник.Номенклатура КАК Номенклатура
		ГДЕ
			НЕ &ИспользуетсяОтборПоСегментуНоменклатуры
			И НЕ Номенклатура.ЭтоГруппа
		{ГДЕ
			Номенклатура.Ссылка.* КАК Номенклатура}) КАК ТаблицаНоменклатуры
	ГДЕ
		ТаблицаНоменклатуры.Номенклатура.ЭтоГруппа = ЛОЖЬ
		И ВЫБОР
				КОГДА &ПолнаяВыгрузка
					ТОГДА ИСТИНА
				ИНАЧЕ ТаблицаНоменклатуры.Номенклатура В
						(ВЫБРАТЬ
							НоменклатураИзменения.Ссылка
						ИЗ
							Справочник.Номенклатура.Изменения КАК НоменклатураИзменения
						ГДЕ
							НоменклатураИзменения.Узел = &Узел)
			КОНЕЦ) КАК НоменклатураСХарактеристиками
		ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.СвободныеОстатки.Остатки(
				,
				Склад В
					(ВЫБРАТЬ
						ВремСклады.Склад
					ИЗ
						ВремСклады)) КАК СвободныеОстаткиОстатки
		ПО НоменклатураСХарактеристиками.Номенклатура = СвободныеОстаткиОстатки.Номенклатура
{ГДЕ
	(ЕСТЬNULL(СвободныеОстаткиОстатки.ВНаличииОстаток, 0)) КАК Остаток}

ИНДЕКСИРОВАТЬ ПО
	Номенклатура
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
	СоглашенияСКлиентами.Ссылка КАК Соглашение,
	"Соглашение" КАК ТипОбъекта
ПОМЕСТИТЬ ВремСоглашения
ИЗ
	Справочник.СоглашенияСКлиентами КАК СоглашенияСКлиентами
ГДЕ
	СоглашенияСКлиентами.Типовое
	И СоглашенияСКлиентами.ДоступноВнешнимПользователям
	И СоглашенияСКлиентами.Статус = ЗНАЧЕНИЕ(Перечисление.СтатусыСоглашенийСКлиентами.Действует)
	И СоглашенияСКлиентами.СегментПартнеров = ЗНАЧЕНИЕ(Справочник.СегментыПартнеров.ПустаяСсылка)
{ГДЕ
	СоглашенияСКлиентами.Ссылка.* КАК Соглашение}

ИНДЕКСИРОВАТЬ ПО
	Соглашение
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ РАЗЛИЧНЫЕ
	"ЕдиницаИзмерения" КАК ТипОбъекта,
	ВремНоменклатура.ЕдиницаИзмерения КАК ЕдиницаИзмерения
ПОМЕСТИТЬ ВремЕдиницыИзмерения
ИЗ
	ВремНоменклатура КАК ВремНоменклатура
ГДЕ
	ВремНоменклатура.ЕдиницаИзмерения <> ЗНАЧЕНИЕ(Справочник.УпаковкиЕдиницыИзмерения.ПустаяСсылка)

ИНДЕКСИРОВАТЬ ПО
	ЕдиницаИзмерения
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВремСоглашения.ТипОбъекта,
	ВремСоглашения.Соглашение КАК Объект
ИЗ
	ВремСоглашения КАК ВремСоглашения

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	ВремЕдиницыИзмерения.ТипОбъекта,
	ВремЕдиницыИзмерения.ЕдиницаИзмерения
ИЗ
	ВремЕдиницыИзмерения КАК ВремЕдиницыИзмерения

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	ВремСклады.ТипОбъекта,
	ВремСклады.Склад
ИЗ
	ВремСклады КАК ВремСклады

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	ВремНоменклатура.ТипОбъекта,
	ВремНоменклатура.Номенклатура
ИЗ
	ВремНоменклатура КАК ВремНоменклатура
;

////////////////////////////////////////////////////////////////////////////////
УНИЧТОЖИТЬ ВремНоменклатура
;

////////////////////////////////////////////////////////////////////////////////
УНИЧТОЖИТЬ ВремСоглашения
;

////////////////////////////////////////////////////////////////////////////////
УНИЧТОЖИТЬ ВремЕдиницыИзмерения
;

////////////////////////////////////////////////////////////////////////////////
УНИЧТОЖИТЬ ВремСклады