Обсуждение к заданию: Сделать вид цен, который будет рассчитывать цену на основании доп реквизитов Номенклатуры

• • #1
  • 10.04.2026 19:15
  0
  Соломатин Денис

  Приватное сообщение
  Сделать вид цен или схему компоновки данных для загрузки в вид цен, который будет рассчитывать цену на основании дополнительных реквизитов Номенклатуры. Дополнительные реквизиты: Длина Ширина ...  Подробнее>>
• • #2
  • 11.04.2026 07:52
  0
  Николай

  Приватное сообщение
  ВЫБРАТЬ
  ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка) КАК Номенклатура,
  ЗНАЧЕНИЕ(Справочник.ХарактеристикиНоменклатуры.ПустаяСсылка) КАК Характеристика,
  ЗНАЧЕНИЕ(Справочник.УпаковкиЕдиницыИзмерения.ПустаяСсылка) КАК Упаковка,
  1 КАК Коэффициент,
  0 КАК Цена,
  ЗНАЧЕНИЕ(Справочник.Валюты.ПустаяСсылка) КАК Валюта
  ПОМЕСТИТЬ втНоменклатура
  {ВЫБРАТЬ
  Номенклатура.*,
  Характеристика.*,
  Упаковка.*,
  Коэффициент,
  Цена,
  Валюта.*}
  ;
  
  ////////////////////////////////////////////////////////////////////////////////
  ВЫБРАТЬ
  втНоменклатура.Номенклатура КАК Номенклатура,
  втНоменклатура.Характеристика КАК Характеристика,
  втНоменклатура.Упаковка КАК Упаковка,
  втНоменклатура.Коэффициент КАК Коэффициент,
  втНоменклатура.Цена КАК Цена,
  втНоменклатура.Валюта КАК Валюта,
  ВЫРАЗИТЬ(ЕСТЬNULL(Длина.Значение, 0) КАК ЧИСЛО(15, 2)) КАК Длина,
  ВЫРАЗИТЬ(ЕСТЬNULL(Ширина.Значение, 0) КАК ЧИСЛО(15, 2)) КАК Ширина,
  ВЫРАЗИТЬ(ЕСТЬNULL(Высота.Значение, 0) КАК ЧИСЛО(15, 2)) КАК Высота
  ПОМЕСТИТЬ втДопРеквизиты
  ИЗ
  втНоменклатура КАК втНоменклатура
  ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Номенклатура.ДополнительныеРеквизиты КАК Длина
  ПО (втНоменклатура.Номенклатура = Длина.Ссылка
  И Длина.Свойство.ИдентификаторДляФормул = "Длина")
  ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Номенклатура.ДополнительныеРеквизиты КАК Ширина
  ПО (втНоменклатура.Номенклатура = Ширина.Ссылка
  И Ширина.Свойство.ИдентификаторДляФормул = "Ширина")
  ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Номенклатура.ДополнительныеРеквизиты КАК Высота
  ПО (втНоменклатура.Номенклатура = Высота.Ссылка
  И Высота.Свойство.ИдентификаторДляФормул = "Высота")
  ;
  
  ////////////////////////////////////////////////////////////////////////////////
  ВЫБРАТЬ
  втДопРеквизиты.Номенклатура КАК Номенклатура,
  втДопРеквизиты.Характеристика КАК Характеристика,
  втДопРеквизиты.Упаковка КАК Упаковка,
  втДопРеквизиты.Коэффициент КАК Коэффициент,
  втДопРеквизиты.Длина * втДопРеквизиты.Ширина * втДопРеквизиты.Высота / 1000 * 0.72 КАК Цена,
  втДопРеквизиты.Валюта КАК Валюта
  ИЗ
  втДопРеквизиты КАК втДопРеквизиты